Não sei se alguém já passou pelo mesmo problema que eu, mas esta semana eu tinha que hospedar um site. Anteriormente eu havia entrado em contato com a empresa de hospedagem, a UAI. Perguntei a eles quais tecnologias eles suportavam, eles me responderam ASP, ASP.Net, entre outras, daí respondi o e-mail com uma nova pergunta, se o ASP.Net que eles suportam é o 1.x ou 2.0, daí eles me responderam que tem suporte ao ASP independente da versão.

Daí ao vendo ele dizer ASP, já imaginei que eles não sabiam direito o que estavam falando. Criei uma página simples em ASP.Net 2.0 e fiz upload....é, não funcionou! Daí resolvi procurar algo na internet que fizesse um teste de um servidor remoto em busca das versões do ASP.Net que estão instaladas. Até que achei este script que acho que poderá ser útil à outras pessoas também.

Portanto, fica aí a dica.

O código do script é:

<%

Dim WshShell, sRegValue, sRegKey
Set WshShell = CreateObject("WScript.Shell")

'Check asp.net
sRegKey = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\ASP.NET"
sRegValue = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\ASP.NET\(default)"

If RegKeyExists(sRegKey) And Not RegValueExists(sRegValue) Then
 Response.Write "<font color = green>ASP.Net is installed on this machine.</font>"
Else
 Response.Write "<font color = red>ASP.Net is Not installed on this machine.</font>"
End If
Response.Write "<br>"

'Check asp.net 1.1
sRegKey = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\ASP.NET_1.1.4322"
sRegValue = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\ASP.NET_1.1.4322\(default)"

If RegKeyExists(sRegKey) And Not RegValueExists(sRegValue) Then
 Response.Write "<font color = green>ASP.Net 1.1 is installed on this machine.</font>"
Else
 Response.Write "<font color = red>ASP.Net 1.1 is Not installed on this machine.</font>"
End If
Response.Write "<br>"

'Check asp.net 2.0
sRegKey = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\ASP.NET_2.0.50727"
sRegValue = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\ASP.NET_2.0.50727\(default)"

If RegKeyExists(sRegKey) And Not RegValueExists(sRegValue) Then
 Response.Write "<font color = green>ASP.Net 2.0 is installed on this machine.</font>"
Else
 Response.Write "<font color = red>ASP.Net 2.0 is Not installed on this machine.</font>"
End If
Response.Write "<br>"

'Check asp.net server state
sRegKey = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\aspnet_state"
sRegValue = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\aspnet_state\(default)"

If RegKeyExists(sRegKey) And Not RegValueExists(sRegValue) Then
 Response.Write "<font color = green>ASP.Net State is installed on this machine.</font>"
Else
 Response.Write "<font color = red>ASP.Net State is Not installed on this machine.</font>"
End If
Response.Write "<br>"

Function RegValueExists(sRegValue)
     ' Returns True or False based of the existence of a registry value.
     Dim oShell, RegReadReturn
     Set oShell = CreateObject("WScript.Shell")
     RegValueExists = True  ' init value
     On Error Resume Next
     RegReadReturn = oShell.RegRead(sRegValue)
     If Err.Number <> 0 Then
       RegValueExists = False
     End if
     On Error Goto 0
End Function

Function RegKeyExists(ByVal sRegKey)
    ' Returns True or False based on the existence of a registry key.

    Dim sDescription, oShell
    Set oShell = CreateObject("WScript.Shell")

    RegKeyExists = True
    sRegKey = Trim (sRegKey)
    If Not Right(sRegKey, 1) = "\" Then
      sRegKey = sRegKey & "\"
    End If

    On Error Resume Next
    oShell.RegRead "HKEYNotAKey\"
    sDescription = Replace(Err.Description, "HKEYNotAKey\", "")

    Err.Clear
    oShell.RegRead sRegKey
    RegKeyExists = sDescription <> Replace(Err.Description, sRegKey, "")
    On Error Goto 0
End Function

'Many thanks to torgeir for posting to google groups
'torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
'Administration scripting examples and an ONLINE version of
'the 1328 page Scripting Guide:
'http://www.microsoft.com/technet/community/scriptcenter/default.mspx
%>

Salve o arquivo com extensão .ASP, faça upload e chame a página.

E pronto.